LoRaWAN

LoRaWan (Long Range Wide Area Network) nutzt eine von Semtech entwickelte proprietäre Funktechnik, die es ermöglicht kostenfrei im lizenzfreien SDR/ISM 868 MHz Band Datenpakete via Funk zu übertragen. Mit dieser Technik werden teilweise beeindruckende Reichweiten von bis zu mehreren Kilometern erzielt.
Das Projekt beinhaltet die Versendung von Sensordaten eines BME280 an TTN. The Things Network ist ein globales, offenes, kostenloses und dezentrales Crowdsourcing-Projekt. Durch die freiwillige Bereitstellung von LoRaWAN-Gateways durch Nutzer wird ein weltweites Netzwerk für Funksignale an TTN realisiert. Dort werden die Signale (z. B. Messdaten, wie beispielsweise von Strom- oder Wasserzählern, CO2-Sensoren) weiter verarbeitet und an definierte Empfänger weitergeleitet.

Hardware

Die Stückliste für das LoRaWAN Projekt:

1 x Heltec LoRa WiFi32

1 x BME280

1 x LoRa Gateway (optional)

Kleinmaterial, Schaltdraht

Verdrahtung

ESP GPIO 21 -> SDA BME280

ESP GPIO 22 -> SCL BME280

ESP 5V -> 5V BME280

ESP GND -> GND BME280

Software

Die Software wird mit der Arduino IDE in den ESP32 geladen.

Programm

C++ Code: LoRa BME280

/*************************************************************************************************
                                      PROGRAMMINFO
**************************************************************************************************
Funktion: LoRa BME280
**************************************************************************************************
Version: 06.07.2022
**************************************************************************************************
Board: Heltec LoRa WiFi 32
**************************************************************************************************
C++ Arduino IDE V1.8.19

**************************************************************************************************
Einstellungen:
https://dl.espressif.com/dl/package_esp32_index.json
http://dan.drown.org/stm32duino/package_STM32duino_index.json
http://arduino.esp8266.com/stable/package_esp8266com_index.json
**************************************************************************************************/



 // Libraries LoRaWAN / SPI / OLED Display

 #include <lmic.h>
 #include <hal/hal.h>
 #include <SPI.h>
 #include <U8x8lib.h>
 #include <U8g2lib.h>


 //Libraries for BME280

 #include <Adafruit_Sensor.h>
 #include <Adafruit_BME280.h>

 //BME280 definition festlegen

 #define SDA 21
 #define SCL 22

 TwoWire I2Cone = TwoWire(1);
 Adafruit_BME280 bme;

 //Paketzähler ID setzen / Strings festlegen

 int readingID = 0;
 int counter = 0;
 String LoRaMessage = "";

 float temperature = 0;
 float humidity = 0;
 float pressure = 0;

 // Zugangsdaten vom TTN / The Things Network
 // (muessen voher bei generiert worden sein)

 // LoRaWAN Network Session Key (drag and drop als msb )
 static const PROGMEM u1_t NWKSKEY[16] = { 0xDC, 0x5D, 0xA2, 0xD6, 0xFB, 0x78, 0x9A, 0x9E, 0xC6, 0x00, 0x9D, 0xBD, 0xA6, 0x5E, 0xxx, 0xxx };




 // LoRaWAN App Session Key (Drag and Drop als msb)
static const u1_t PROGMEM APPSKEY[16] = { 0x6E, 0xB3, 0xC4, 0x6F, 0x38, 0x2C, 0xD8, 0xB7, 0x61, 0x89, 0xD1, 0x87, 0xDE, 0xB9, 0xx, 0xxx };


 // LoRaWAN Device Addresse
static const u4_t DEVADDR = 0x260BB7xx;


 void startBME(){

   delay(1000);


   I2Cone.begin(SDA, SCL, 100000);
   bool status1 = bme.begin(0x76, &I2Cone);
   if (!status1) {
     Serial.println("Kein BME280 Sensor gefunden!");
     while (1);
   }

   delay(3000);

 }

 // Display passend konfigurieren

 U8G2_SSD1306_128X64_NONAME_F_SW_I2C u8g2(U8G2_R0, /* clock=*/ 15, /* data=*/ 4, /* reset=*/ 16);
 U8X8_SSD1306_128X64_NONAME_SW_I2C u8x8(15, 4, 16);



 // Um Grafiken umzuwandeln sollte diese in S/W sein die passende Groesse hier 128x64 Pixel haben
 // und als xbm exportiert werden.


 static unsigned char TK_OLED_SOURCE_bits[] = {
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x80, 0xff, 0xff, 0x01, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0xe0, 0x01,
   0x80, 0x07, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x78, 0x00, 0x00, 0x00, 0x00, 0x1e, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x80, 0x01, 0x00, 0x00, 0x00, 0x00, 0x80, 0x01,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x1e, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x78, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x80,
   0x01, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x80, 0x01, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x78, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x1e, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x1e, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x78, 0x00, 0x00, 0x00, 0x00, 0x00, 0xe0, 0x01,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x80, 0x07, 0x00, 0x00,
   0x00, 0x00, 0x78, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x1e, 0x00, 0x00, 0x00, 0x00, 0x1e, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x78, 0x00, 0x00, 0x00, 0x80, 0x07, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0xe0, 0x01, 0x00,
   0x00, 0x80, 0x01, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x80, 0x01, 0x00, 0x00, 0xe0, 0x01, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x80, 0x07, 0x00, 0x00, 0x78, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x1e, 0x00,
   0x00, 0x18, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x18, 0x00, 0x00, 0x06, 0x00, 0x00, 0x80, 0x7f, 0x00, 0x00,
   0x00, 0x00, 0xfe, 0x01, 0x00, 0x00, 0x60, 0x00, 0x80, 0x07, 0x00, 0x00,
   0xe0, 0xff, 0x01, 0x00, 0x00, 0x80, 0xff, 0x07, 0x00, 0x00, 0xe0, 0x01,
   0x80, 0x01, 0x00, 0x00, 0xf8, 0xff, 0x07, 0x00, 0x00, 0xe0, 0xff, 0x1f,
   0x00, 0x00, 0x80, 0x01, 0x80, 0x01, 0x00, 0x00, 0xf8, 0xff, 0x07, 0x00,
   0x00, 0xe0, 0xff, 0x1f, 0x00, 0x00, 0x80, 0x01, 0x60, 0x00, 0x00, 0x00,
   0xf8, 0xff, 0x07, 0x00, 0x00, 0xe0, 0xff, 0x1f, 0x00, 0x00, 0x00, 0x06,
   0x60, 0x00, 0x00, 0x00, 0xf8, 0xff, 0x07, 0x00, 0x00, 0xe0, 0xff, 0x1f,
   0x00, 0x00, 0x00, 0x06, 0x78, 0x00, 0x00, 0x00, 0xf8, 0xff, 0x07, 0x00,
   0x00, 0xe0, 0xff, 0x1f, 0x00, 0x00, 0x00, 0x1e, 0x18, 0x00, 0x00, 0x00,
   0xf8, 0xff, 0x07, 0x00, 0x00, 0xe0, 0xff, 0x1f, 0x00, 0x00, 0x00, 0x18,
   0x18, 0x00, 0x00, 0x00, 0xf8, 0xff, 0x07, 0x00, 0x00, 0xe0, 0xff, 0x1f,
   0x00, 0x00, 0x00, 0x18, 0x18, 0x00, 0x00, 0x00, 0xe0, 0xff, 0x01, 0x00,
   0x00, 0x80, 0xff, 0x07, 0x00, 0x00, 0x00, 0x18, 0x18, 0x00, 0x00, 0x00,
   0x80, 0x7f, 0x00, 0x00, 0x00, 0x00, 0xfe, 0x01, 0x00, 0x00, 0x00, 0x18,
   0x1e, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x78, 0x07, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0xe0, 0x07, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0xe0,
   0x07, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0xe0, 0x07, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0xe0, 0x07, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0xe0,
   0x07, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0xe0, 0x07, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0xe0, 0x07, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0xe0,
   0x1e, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x78, 0x18, 0x80, 0x01, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x80, 0x01, 0x18, 0x18, 0x80, 0x07, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0xe0, 0x01, 0x18,
   0x18, 0x00, 0x06, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x60, 0x00, 0x18, 0x18, 0x00, 0x06, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x60, 0x00, 0x18, 0x78, 0x00, 0x1e, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x78, 0x00, 0x1e,
   0x60, 0x00, 0x18, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x18, 0x00, 0x06, 0x60, 0x00, 0x78, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x1e, 0x00, 0x06, 0x80, 0x01, 0x60, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x06, 0x80, 0x01,
   0x80, 0x01, 0xe0, 0x01, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x80, 0x07, 0x80, 0x01, 0x80, 0x07, 0x80, 0x07, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0xe0, 0x01, 0xe0, 0x01, 0x00, 0x06, 0x00, 0x1e,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x78, 0x00, 0x60, 0x00,
   0x00, 0x18, 0x00, 0x7e, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x7e, 0x00, 0x18, 0x00, 0x00, 0x78, 0x00, 0xf8, 0x01, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x80, 0x1f, 0x00, 0x1e, 0x00, 0x00, 0xe0, 0x01, 0xe0,
   0x07, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0xe0, 0x07, 0x80, 0x07, 0x00,
   0x00, 0x80, 0x01, 0x00, 0x1e, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x78,
   0x00, 0x80, 0x01, 0x00, 0x00, 0x80, 0x07, 0x00, 0x78, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x1e, 0x00, 0xe0, 0x01, 0x00, 0x00, 0x00, 0x1e, 0x00,
   0x80, 0x07, 0x00, 0x00, 0x00, 0x00, 0xe0, 0x01, 0x00, 0x78, 0x00, 0x00,
   0x00, 0x00, 0x78, 0x00, 0x00, 0x78, 0x00, 0x00, 0x00, 0x00, 0x1e, 0x00,
   0x00, 0x1e, 0x00, 0x00, 0x00, 0x00, 0xe0, 0x01, 0x00, 0x00, 0x1e, 0x00,
   0x00, 0x78, 0x00, 0x00, 0x80, 0x07, 0x00, 0x00, 0x00, 0x00, 0x00, 0x1e,
   0x00, 0x00, 0x00, 0xf8, 0x1f, 0x00, 0x00, 0x00, 0x78, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x78, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x1e, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x80, 0x01, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x80, 0x01, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x1e, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x78, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x80, 0x01, 0x00, 0x00, 0x00, 0x00, 0x80, 0x01,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x78, 0x00, 0x00,
   0x00, 0x00, 0x1e, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0xe0, 0x01, 0x80, 0x07, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x80, 0xff, 0xff, 0x01, 0x00, 0x00,
   0x00, 0x00, 0x00, 0x00  };



 #define uS_TO_S_FACTOR 1000000  // Umberechnungsfaktor Mikro Sekunden auf Sekunden
 #define TIME_TO_SLEEP  30      // Dauer des Tiefschlafzustands in Sekunden
 RTC_DATA_ATTR int bootCount = 0;



 // These callbacks are only used in over-the-air activation, so they are
 // left empty here (we cannot leave them out completely unless
 // DISABLE_JOIN is set in config.h, otherwise the linker will complain).
 void os_getArtEui (u1_t* buf) { }
 void os_getDevEui (u1_t* buf) { }
 void os_getDevKey (u1_t* buf) { }

 static osjob_t sendjob;

 // Senden alle 120 Sekunden
 const unsigned TX_INTERVAL = 60;

 // LoRa Heltec V2 Pin Map setzen

 const lmic_pinmap lmic_pins = { .nss = 18, .rxtx = LMIC_UNUSED_PIN, .rst = 14, .dio = {34, 26, 35}, };


 void do_send(osjob_t* j) {
   // Check if there is not a current TX/RX job running
   if (LMIC.opmode & OP_TXRXPEND) {
     Serial.println(F("OP_TXRXPEND, nicht senden"));
   } else {
     // Prepare upstream data transmission at the next possible time.


 startBME();

   temperature = bme.readTemperature();
   humidity = bme.readHumidity();
   pressure = bme.readPressure() / 100.0F;
   Serial.print("Senden des LoRa-Pakets an TTN Gatway: ");
   Serial.print("Senden der Daten:");

   //LoRaMessage = String(temperature) + "/" + String(humidity) + "/" + String(pressure);
   LoRaMessage = String(temperature) + " C" + "| " + String(humidity) +" %" + "| " + String(pressure) + " mB ";
   Serial.println(LoRaMessage);


     int test_length = LoRaMessage.length();
     uint8_t payload [test_length];
     for (int i = 0; i < test_length; i++){
         payload[i] = uint8_t (LoRaMessage[i]);
     }

 LMIC_setTxData2(1, payload, sizeof(payload)-1, 0);


     Serial.println(F("Paket in der Warteschlange"));
   }



   // Next TX is scheduled after TX_COMPLETE event.
 }

 void setup() {

  u8g2.begin();
  u8g2.clearBuffer();          // Internen Display Speicher komplett löschen
  u8g2.drawXBM(0,0, 128, 64, TK_OLED_SOURCE_bits);
  u8g2.sendBuffer();          // Inhalt des Speichers direkt auf das Display pushen

  delay (2000);

   u8x8.begin();
   u8x8.clear();
   u8x8.setFont(u8x8_font_chroma48medium8_r);
   u8x8.drawString(0, 2, "Read: BME280 " );
   delay (2000);

   u8x8.clear();
   u8x8.drawString(0, 2, " Push Message to");
   u8x8.drawString(0, 3, "   TTN Gateway  ");
   delay(1500);
   u8x8.clear();
   u8x8.drawString(0, 4, "     & sleep       ");
   u8x8.drawString(0, 6, "  ..for 60 sec  ");
   delay (1500);
   u8x8.clear();
   u8x8.begin();
   u8x8.setFont(u8x8_font_open_iconic_weather_4x4);
   u8x8.drawString(0, 2, "A"  );
   u8x8.setFont(u8x8_font_chroma48medium8_r);
   u8x8.drawString(4, 3, "Send Data.." );
   delay (3000);
   u8x8.clear();


   Serial.begin(115200);
   SPI.begin(5, 19, 27, 18);
   //Belegung Heltec LoRa V2 Board
   Serial.println(F("Booten..."));


   // LMIC init
   os_init();
   // Reset the MAC state. Session and pending data transfers will be discarded.
   LMIC_reset();

   // Set static session parameters. Instead of dynamically establishing a session
   // by joining the network, precomputed session parameters are be provided.
 #ifdef PROGMEM
   // On AVR, these values are stored in flash and only copied to RAM
   // once. Copy them to a temporary buffer here, LMIC_setSession will
   // copy them into a buffer of its own again.
   uint8_t appskey[sizeof(APPSKEY)];
   uint8_t nwkskey[sizeof(NWKSKEY)];
   memcpy_P(appskey, APPSKEY, sizeof(APPSKEY));
   memcpy_P(nwkskey, NWKSKEY, sizeof(NWKSKEY));
   LMIC_setSession (0x1, DEVADDR, nwkskey, appskey);
 #else
   // If not running an AVR with PROGMEM, just use the arrays directly
   LMIC_setSession (0x1, DEVADDR, NWKSKEY, APPSKEY);
 #endif

 #if defined(CFG_eu868)
   // Set up the channels used by the Things Network, which corresponds
   // to the defaults of most gateways. Without this, only three base
   // channels from the LoRaWAN specification are used, which certainly
   // works, so it is good for debugging, but can overload those
   // frequencies, so be sure to configure the full frequency range of
   // your network here (unless your network autoconfigures them).
   // Setting up channels should happen after LMIC_setSession, as that
   // configures the minimal channel set.
   // NA-US channels 0-71 are configured automatically

   LMIC_setupChannel(0, 868100000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
   LMIC_setupChannel(1, 868300000, DR_RANGE_MAP(DR_SF12, DR_SF7B), BAND_CENTI);      // g-band
   LMIC_setupChannel(2, 868500000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
   LMIC_setupChannel(3, 867100000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
   LMIC_setupChannel(4, 867300000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
   LMIC_setupChannel(5, 867500000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
   LMIC_setupChannel(6, 867700000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
   LMIC_setupChannel(7, 867900000, DR_RANGE_MAP(DR_SF12, DR_SF7),  BAND_CENTI);      // g-band
   LMIC_setupChannel(8, 868800000, DR_RANGE_MAP(DR_FSK,  DR_FSK),  BAND_MILLI);      // g2-band

   //LMIC_disableChannel(0); //Send only at channel 0
   LMIC_disableChannel(1);
   LMIC_disableChannel(2);
   LMIC_disableChannel(3);
   LMIC_disableChannel(4);
   LMIC_disableChannel(5);
   LMIC_disableChannel(6);
   LMIC_disableChannel(7);
   LMIC_disableChannel(8);

   // TTN defines an additional channel at 869.525Mhz using SF9 for class B
   // devices' ping slots. LMIC does not have an easy way to define set this
   // frequency and support for class B is spotty and untested, so this
   // frequency is not configured here.
 #elif defined(CFG_us915)
   // NA-US channels 0-71 are configured automatically
   // but only one group of 8 should (a subband) should be active
   // TTN recommends the second sub band, 1 in a zero based count.
   // <nowiki>https://github.com/TheThingsNetwork/gateway-conf/blob/master/US-global_conf.json</nowiki>
   LMIC_selectSubBand(1);
 #endif

   // Disable link check validation
   LMIC_setLinkCheckMode(0);

   // TTN uses SF9 for its RX2 window.
   LMIC.dn2Dr = DR_SF9;

   // Set data rate and transmit power for uplink (note: txpow seems to be ignored by the library)
   LMIC_setDrTxpow(DR_SF7, 14);

   // Start job
   do_send(&sendjob);

 }

 void loop() {
   os_runloop_once();
    }

 void onEvent (ev_t ev) {
   Serial.print(os_getTime());
   Serial.print(": ");
   switch (ev) {
     case EV_SCAN_TIMEOUT:
       Serial.println(F("EV_SCAN_TIMEOUT"));
       break;
     case EV_BEACON_FOUND:
       Serial.println(F("EV_BEACON_FOUND"));
       break;
     case EV_BEACON_MISSED:
       Serial.println(F("EV_BEACON_MISSED"));
       break;
     case EV_BEACON_TRACKED:
       Serial.println(F("EV_BEACON_TRACKED"));
       break;
     case EV_JOINING:
       Serial.println(F("EV_JOINING"));
       break;
     case EV_JOINED:
       Serial.println(F("EV_JOINED"));
       break;
     case EV_RFU1:
       Serial.println(F("EV_RFU1"));
       break;
     case EV_JOIN_FAILED:
       Serial.println(F("EV_JOIN_FAILED"));
       break;
     case EV_REJOIN_FAILED:
       Serial.println(F("EV_REJOIN_FAILED"));
       break;
     case EV_TXCOMPLETE:
       Serial.println(F("EV_TX komplett"));
       if (LMIC.txrxFlags & TXRX_ACK)
         Serial.println(F("Eingegangen ack"));
       if (LMIC.dataLen) {
         Serial.println(F("Eingegangen "));
         Serial.println(LMIC.dataLen);
         Serial.println(F(" bytes payload"));
       }
       // Schedule next transmission
       os_setTimedCallback(&sendjob, os_getTime() + sec2osticks(TX_INTERVAL), do_send);
       break;
     case EV_LOST_TSYNC:
       Serial.println(F("EV_LOST_TSYNC"));
       break;
     case EV_RESET:
       Serial.println(F("EV_RESET"));
       break;
     case EV_RXCOMPLETE:
       // data received in ping slot
       Serial.println(F("EV_RXCOMPLETE"));
       break;
     case EV_LINK_DEAD:
       Serial.println(F("EV_LINK_DEAD"));
       break;
     case EV_LINK_ALIVE:
       Serial.println(F("EV_LINK_ALIVE"));
       break;
     default:
       Serial.println(F("Unbekanntes Ereignis"));
       break;
   }

 }

RAW code

Überprüfung der gesendeten Sensorwerte am Serieller Monitor

Einrichtung des LoRa Gateways

Payload Monitor von TTN

Zwei LoRa-Boards können auch ohne Gateway direkt über eine Punkt zu Punkt Verbindung miteinander kommunizieren. Im nächsten Beispiel ist der Sender mit einem Partikel-Sensor SDS11 ausgestattet und sendet die Daten zu einem LoRa-Board, dass die Daten in einem WEB-Server anzeigt. Die IP-Adresse des WEB-Servers wird nach dem Start am Display angezeigt.

Programme

C++ Code: LoRa Sender

/*************************************************************************************************
                                      PROGRAMMINFO
**************************************************************************************************
Funktion: LORA Sender SDS011 (COM15)
**************************************************************************************************
Version: 14.06.2022
**************************************************************************************************
Board: HELTEC WLAN LORA 32
**************************************************************************************************
*PM2.5 steht beispielsweise fuer Partikel mit einem aerodynamischen Durchmesser von 2,5 Mikrometer oder weniger, PM10 fuer 10 Mikrometern

  SDS011 (Laser Dust/Air Quality Sensor Module)
  Specification:
  Measured values: PM2.5, PM10
  Range: 0 - 999.9 ug /m3
  Supply voltage: 5V (4.7 - 5.3V)
  Power consumption (work): 70mA+-10mA
  Power consumption (sleep mode laser & fan): < 4mA
  Storage temperature: -20 to +60C
  Work temperature: -10 to +50C
  Humidity (storage): Max. 90%
  Humidity (work): Max. 70% (condensation of water vapor falsify readings)
  Accuracy:
  70% for 0.3um
  98% for 0.5um
  Size: 71x70x23 mm
  Certification: CE, FCC, RoHS
  Pinout:
  Pin 1 - not connected
  Pin 2 - PM2.5: 0-999ug/m3; PWM output
  Pin 3 - 5V
  Pin 4 - PM10: 0-999 ug/m3; PWM output
  Pin 5 - GND
  Pin 6 - RX UART (TTL) 3.3V
  Pin 7 - TX UART (TTL) 3.3V
**************************************************************************************************
Libraries:
https://github.com/espressif/arduino-esp32/tree/master/libraries
**************************************************************************************************
C++ Arduino IDE V1.8.19
**************************************************************************************************
Einstellungen:
https://dl.espressif.com/dl/package_esp32_index.json
http://dan.drown.org/stm32duino/package_STM32duino_index.json
http://arduino.esp8266.com/stable/package_esp8266com_index.json
**************************************************************************************************/

//LoRa Libraries
#include <SPI.h>
#include <LoRa.h>

//OLED Display Libraries
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

//PWM Sensoreing�nge
int PM25 = 36;
int PM10 = 37;

float PM25Readin = 25;
float PM10Readin = 10;

//LoRa-Modul Pins
#define SCK 5
#define MISO 19
#define MOSI 27
#define SS 18
#define RST 14
#define DIO0 26

//Frequenz fuer Europa
#define BAND 866E6

//OLED Pins
#define OLED_SDA 4
#define OLED_SCL 15
#define OLED_RST 16
#define SCREEN_WIDTH 128 // OLED Breite
#define SCREEN_HEIGHT 64 // OLED H�he

TwoWire I2Cone = TwoWire(1);

//Packet Counter
int readingID = 0;

int counter = 0;
String LoRaMessage = "";

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RST);

//Initialisiere OLED Display
void startOLED(){
  //OLED Reset
  pinMode(OLED_RST, OUTPUT);
  digitalWrite(OLED_RST, LOW);
  delay(20);
  digitalWrite(OLED_RST, HIGH);

  //Initialisiere OLED Display
  Wire.begin(OLED_SDA, OLED_SCL);
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3c, false, false)) { // Address 0x3C for 128x32
    Serial.println(F("SSD1306 allocation failed"));
    for(;;); // Don't proceed, loop forever
  }
  display.clearDisplay();
  display.setTextColor(WHITE);
  display.setTextSize(1);
  display.setCursor(0,0);
  display.print("LORA SENDER");
}

//Initialisiere LoRa
void startLoRA(){
  //SPI LoRa pins
  SPI.begin(SCK, MISO, MOSI, SS);
  //Setup LoRa Sende Modul
  LoRa.setPins(SS, RST, DIO0);

  while (!LoRa.begin(BAND) && counter < 10) {
    Serial.print(".");
    counter++;
    delay(500);
  }
  if (counter == 10) {
    // Erh�he die Lese-ID f�r jede neue Lesung
    readingID++;
    Serial.println("Starting LoRa failed!");
  }
  Serial.println("LoRa-Initialisierung OK!");
  display.setCursor(0,10);
  display.clearDisplay();
  display.print("LoRa-Initialisierung OK!");
  display.display();
  delay(2000);
}

void getReadings(){
   PM25Readin = analogRead(36);
   PM25Readin = map(PM25Readin, 0, 4095, 0, 1000);
   PM10Readin = analogRead(37);
   PM10Readin = map(PM10Readin, 0, 4095, 0, 1000);

    //Kalibrierung:
    PM25Readin=PM25Readin/134,23;
    PM10Readin=PM10Readin/84,63;


   Serial.println("PM25Readin: ");
   Serial.println(PM25Readin);
   Serial.println("PM10Readin: ");
   Serial.println(PM10Readin);
}


void sendReadings() {
  LoRaMessage = String(readingID) + "/" + String(PM25Readin) + "&" + String(PM10Readin);
  //Send LoRa packet to receiver
  LoRa.beginPacket();
  LoRa.print(LoRaMessage);
  LoRa.endPacket();

  display.clearDisplay();
  display.setCursor(0,0);
  display.setTextSize(1);
  display.print("LoRa Packet gesendet!");
  display.setCursor(0,20);
  display.print("PM25: ");
  display.setCursor(44,20);
  display.print(PM25Readin);
  display.setCursor(0,30);
  display.print("PM10: ");
  display.setCursor(44,30);
  display.print(PM10Readin);

  display.setCursor(0,40);
  display.print("Lese-ID:");
  display.setCursor(75,40);
  display.print(readingID);
  display.display();
  Serial.print("Paket senden: ");
  Serial.println(readingID);
  readingID++;
}

void setup() {
  //Intialisiere Serial Monitor
  Serial.begin(115200);
  startOLED();
  startLoRA();
}
void loop() {

  getReadings();
  sendReadings();
  delay(10000);
}

RAW code

C++ Code: LoRa Empfänger

/*************************************************************************************************
                                      PROGRAMMINFO
**************************************************************************************************
Funktion: LoRa WAN WEB-Server SDS011 A169 COM6
**************************************************************************************************
Version: 14.06.022
**************************************************************************************************
Board: TTGO Lora32-OLED V1
**************************************************************************************************
*PM2.5 steht beispielsweise fuer Partikel mit einem aerodynamischen Durchmesser von 2,5 Mikrometer oder weniger, PM10 fuer 10 Mikrometern

  SDS011 (Laser Dust/Air Quality Sensor Module)
  Specification:
  Measured values: PM2.5, PM10
  Range: 0 - 999.9 ug /m3
  Supply voltage: 5V (4.7 - 5.3V)
  Power consumption (work): 70mA+-10mA
  Power consumption (sleep mode laser & fan): < 4mA
  Storage temperature: -20 to +60C
  Work temperature: -10 to +50C
  Humidity (storage): Max. 90%
  Humidity (work): Max. 70% (condensation of water vapor falsify readings)
  Accuracy:
  70% for 0.3um
  98% for 0.5um
  Size: 71x70x23 mm
  Certification: CE, FCC, RoHS
  Pinout:
  Pin 1 - not connected
  Pin 2 - PM2.5: 0-999ug/m3; PWM output
  Pin 3 - 5V
  Pin 4 - PM10: 0-999 ug/m3; PWM output
  Pin 5 - GND
  Pin 6 - RX UART (TTL) 3.3V
  Pin 7 - TX UART (TTL) 3.3V
**************************************************************************************************
Libraries:
https://github.com/espressif/arduino-esp32/tree/master/libraries
**************************************************************************************************
C++ Arduino IDE V1.8.19
**************************************************************************************************
Einstellungen:
https://dl.espressif.com/dl/package_esp32_index.json
http://dan.drown.org/stm32duino/package_STM32duino_index.json
http://arduino.esp8266.com/stable/package_esp8266com_index.json
**************************************************************************************************/
// Import Wi-Fi Library
#include <WiFi.h>
#include "ESPAsyncWebServer.h"

#include <SPIFFS.h>

//LoRa Libraries
#include <SPI.h>
#include <LoRa.h>

//OLED Display Libraries
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

//NTP Server Libraries
#include <NTPClient.h>
#include <WiFiUdp.h>

//Pins des LoRa-Transceiver-Moduls
#define SCK 5
#define MISO 19
#define MOSI 27
#define SS 18
#define RST 14
#define DIO0 26

//Europa Frequenz 866MHz
#define BAND 866E6

//TTGO OLED Pins
#define OLED_SDA 21
#define OLED_SCL 22
#define OLED_RST 16

/*HELTEC Pins
#define OLED_SDA 4
#define OLED_SCL 15
#define OLED_RST 16
*/
#define SCREEN_WIDTH 128 // Breite OLED Display 128 Pixel
#define SCREEN_HEIGHT 64 // H�he OLED Display 64 Pixel

// WiFi Zugang
const char* ssid     = "xxx";
const char* password = "xxx";

// NTP Client
WiFiUDP ntpUDP;
NTPClient timeClient(ntpUDP);

// Variablen fue Datum und Zeit
String formattedDate;
String day;
String hour;
String timestamp;


// Initialisiere LoRa Variablen
int rssi;
String loRaMessage;
String PM25Readin;
String PM10Readin;
String readingID;

// AsyncWebServer Port 80
AsyncWebServer server(80);

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RST);

// Ersetzt Platzhalter der PWM EIngaenge
/*Die Received Signal Strength Indication (RSSI) ist die empfangene Signalleistung
 * in Milliwatt und wird in dBm gemessen.
 */
String processor(const String& var){
  //Serial.println(var);
  if(var == "PM25"){
    return PM25Readin;
  }
    else if(var == "PM10"){
    return PM10Readin;
  }
  else if(var == "TIMESTAMP"){
    return timestamp;
  }
  else if (var == "RRSI"){
    return String(rssi);
  }
  return String();
}

//Initialisiere OLED Display
void startOLED(){
  //Reset OLED Display
  pinMode(OLED_RST, OUTPUT);
  digitalWrite(OLED_RST, LOW);
  delay(20);
  digitalWrite(OLED_RST, HIGH);

  //Initialisiere OLED Display
  Wire.begin(OLED_SDA, OLED_SCL);
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3c, false, false)) { // Adresse 0x3C
    Serial.println(F("SSD1306-Initialisierung fehlgeschlagen"));
    for(;;); // Schleife beenden
  }
  display.clearDisplay();
  display.setTextColor(WHITE);
  display.setTextSize(1);
  display.setCursor(0,0);
  display.print("LORA SENDER");
}

//Initialisiere LoRa Modul
void startLoRA(){
  int counter;
  //SPI LoRa Pins
  SPI.begin(SCK, MISO, MOSI, SS);
  //LoRa-Empfaenger-Modul einrichten
  LoRa.setPins(SS, RST, DIO0);

  while (!LoRa.begin(BAND) && counter < 10) {
    Serial.print(".");
    counter++;
    delay(500);
  }
  if (counter == 10) {
    // Erh�he die Lese-ID bei jedem neuen Messwert
    Serial.println("LoRa Start fehlgeschlagen!");
  }
  Serial.println("LoRa Init. OK!");
  display.setCursor(0,10);
  display.clearDisplay();
  display.print("LoRa Init. OK!");
  display.display();
  delay(2000);
}

void connectWiFi(){
  // Verbindung dem Wi-Fi-Netzwerk mit SSID und Passwort
  Serial.print("Verbinde mit ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // Lokale IP-Adresse ausgeben und Webserver starten
  Serial.println("");
  Serial.println("WiFi verbunden.");
  Serial.println("IP Adresse: ");
  Serial.println(WiFi.localIP());
  display.setCursor(0,25);
  display.print("Web-Server Adresse: ");
  display.setCursor(0,40);
  display.print(WiFi.localIP());
  display.display();
}

// Sensormesswerte vom LoRa-Paket lesen
void getLoRaData() {
  Serial.print("Lora-Paket empfangen: ");
  // Lese Packet
  while (LoRa.available()) {
    String LoRaData = LoRa.readString();
    // LoRaData-Format: LeseID/PM25&PM10#xx
    // String example: 1/2.5&10#xx
    Serial.print(LoRaData);

    // Holen die ReadingID, PM25 und PM10
    int pos1 = LoRaData.indexOf('/');
    int pos2 = LoRaData.indexOf('&');
    int pos3 = LoRaData.indexOf('#');
    readingID = LoRaData.substring(0, pos1);
    PM25Readin = LoRaData.substring(pos1 +1, pos2);
    PM10Readin = LoRaData.substring(pos2 +1, pos3);
//    xx = LoRaData.substring(pos3+1, LoRaData.length());
  }
  // Hole RSSI Received Signal Strength Indication
  rssi = LoRa.packetRssi();
  Serial.print(" Signalst�rke: ");
  Serial.println(rssi);
}

// Datum und Zeit vom NTPClient
void getTimeStamp() {
  while(!timeClient.update()) {
    timeClient.forceUpdate();
  }
  // Das formattedDate hat das folgendes Format:
  // 2018-05-28T16:00:13Z
  // Datum und Uhrzeit extrahieren
  formattedDate = timeClient.getFormattedDate();
  Serial.println(formattedDate);

  // Datum
  int splitT = formattedDate.indexOf("T");
  day = formattedDate.substring(0, splitT);
  Serial.println(day);
  // Zeit
  hour = formattedDate.substring(splitT+1, formattedDate.length()-1);
  Serial.println(hour);
  timestamp = day + " " + hour;
}

void setup() {
  // Initialisiere Seriellen Monitor
  Serial.begin(115200);
  startOLED();
  startLoRA();
  connectWiFi();

  if(!SPIFFS.begin()){
    Serial.println("Beim Mounten von SPIFFS ist ein Fehler aufgetreten");
    return;
  }
  // Starte Index.html
  server.on("/", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send(SPIFFS, "/index.html", String(), false, processor);
  });
  server.on("/PM25", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send_P(200, "text/plain", PM25Readin.c_str());
  });
  server.on("/PM10", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send_P(200, "text/plain", PM10Readin.c_str());
  });
  server.on("/timestamp", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send_P(200, "text/plain", timestamp.c_str());
  });
  server.on("/rssi", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send_P(200, "text/plain", String(rssi).c_str());
  });
  server.on("/winter", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send(SPIFFS, "/winter.jpg", "image/jpg");
  });
  // Starte Server
  server.begin();

  // Initialisiere NTPClient
  timeClient.begin();
  // Zeit-Offset GMT +2 Stunden = 7200;
  timeClient.setTimeOffset(7200);
}

void loop() {
  // LoRa Pakete verf�gbar?
  int packetSize = LoRa.parsePacket();
  if (packetSize) {
    getLoRaData();
    getTimeStamp();
  }
}

RAW code

Download data Ordner

Der Serielle Monitor am Empfänger

Display am Empfänger

Display am Sender

Partikel-Messung WEB-Server

Ein weiters Beispiel zeigt zwei LoRa-Boards mit Punkt zu Punkt-Verbindung. Der Sender beinhaltet einen BME280 und sendet über LoRa die Temperatur, die Luftfeuchte und den Luftdruck an den LoRa-Empfänger. Der Empfänger stellt die empfangenen Werte mit einem WEB-Server dar. Die IP-Adresse des WEB-Servers wird nach dem Start am Display angezeigt.

Programme

C++ Code: LoRa BME-Sender

/*************************************************************************************************
                                      PROGRAMMINFO
**************************************************************************************************
Funktion: LoRa Heltec BME280 Sender A177

**************************************************************************************************
Version: 11.07.2022
**************************************************************************************************
Board: Heltec WiFI LoRa 32
**************************************************************************************************
Libraries:
https://github.com/espressif/arduino-esp32/tree/master/libraries
C:\Users\User\Documents\Arduino
D:\gittemp\Arduino II\A156_Wetterdaten_V3
**************************************************************************************************
C++ Arduino IDE V1.8.19
**************************************************************************************************
Einstellungen:
https://dl.espressif.com/dl/package_esp32_index.json
http://dan.drown.org/stm32duino/package_STM32duino_index.json
http://arduino.esp8266.com/stable/package_esp8266com_index.json
**************************************************************************************************/

//Libraries LoRa
#include <SPI.h>
#include <LoRa.h>

//Libraries  OLED Display
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

//Libraries BME280
#include <Adafruit_Sensor.h>
#include <Adafruit_BME280.h>

//define die Pins, die vom LoRa-Transceiver-Modul verwendet werden
#define SCK 5
#define MISO 19
#define MOSI 27
#define SS 18
#define RST 14
#define DIO0 26

//433E6  Asia
//866E6  Europe
//915E6  North America
#define BAND 866E6

//OLED Pins
#define OLED_SDA 4
#define OLED_SCL 15
#define OLED_RST 16
#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels

//BME280 Pins
#define SDA 21
#define SCL 22

TwoWire I2Cone = TwoWire(1);
Adafruit_BME280 bme;

//Packet Zaehler
int readingID = 0;

int counter = 0;
String LoRaMessage = "";

float temperature = 0;
float humidity = 0;
float pressure = 0;

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RST);

//Initialsiere OLED display
void startOLED(){
  //Reset OLED Display
  pinMode(OLED_RST, OUTPUT);
  digitalWrite(OLED_RST, LOW);
  delay(20);
  digitalWrite(OLED_RST, HIGH);

  //Initialisiere OLED
  Wire.begin(OLED_SDA, OLED_SCL);
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3c, false, false)) { // Address 0x3C for 128x32
    Serial.println(F("SSD1306 allocation failed"));
    for(;;); // Don't proceed, loop forever
  }
  display.clearDisplay();
  display.setTextColor(WHITE);
  display.setTextSize(1);
  display.setCursor(0,0);
  display.print("LORA SENDER");
}

//Initialisiere LoRa Modul
void startLoRA(){
  //SPI LoRa Pins
  SPI.begin(SCK, MISO, MOSI, SS);
  //Setup LoRa Sender Modul
  LoRa.setPins(SS, RST, DIO0);

  while (!LoRa.begin(BAND) && counter < 10) {
    Serial.print(".");
    counter++;
    delay(500);
  }
  if (counter == 10) {
    // Erhöhe die Lese-ID bei jedem neuen Messwert
    readingID++;
    Serial.println("Das Starten von LoRa ist fehlgeschlagen!");
  }
  Serial.println("LoRa-Initialisierung OK!");
  display.setCursor(0,10);
  display.clearDisplay();
  display.print("LoRa-Initialisierung OK!");
  display.display();
  delay(2000);
}

void startBME(){
  I2Cone.begin(SDA, SCL, 100000);
  bool status1 = bme.begin(0x76, &I2Cone);
  if (!status1) {
    Serial.println("Konnte keinen gültigen BME280_1 Sensor finden, Verkabelung überprüfen!");
    while (1);
  }
}

void getReadings(){
  temperature = bme.readTemperature();
  humidity = bme.readHumidity();
  pressure = bme.readPressure() / 100.0F;
}

void sendReadings() {
  LoRaMessage = String(readingID) + "/" + String(temperature) + "&" + String(humidity) + "#" + String(pressure);
  //Send LoRa packet to receiver
  LoRa.beginPacket();
  LoRa.print(LoRaMessage);
  LoRa.endPacket();

  display.clearDisplay();
  display.setCursor(0,0);
  display.setTextSize(1);
  display.print("LoRa-Paket gesendet!");
  display.setCursor(0,20);
  display.print("Temperatur:");
  display.setCursor(72,20);
  display.print(temperature);
  display.setCursor(0,30);
  display.print("Luftfeuchte:");
  display.setCursor(72,30);
  display.print(humidity);
  display.setCursor(0,40);
  display.print("Luftdruck:");
  display.setCursor(72,40);
  display.print(pressure);
  display.setCursor(0,50);
  display.print("Lese-ID:");
  display.setCursor(72,50);
  display.print(readingID);
  display.display();
  Serial.print("Paket senden: ");
  Serial.println(readingID);
  readingID++;
}

void setup() {
  //initialize Serial Monitor
  Serial.begin(115200);
  startOLED();
  startBME();
  startLoRA();
}
void loop() {
  getReadings();
  sendReadings();
  delay(10000);
}

RAW code

C++ Code: LoRa BME-Empfänger

/*************************************************************************************************
                                      PROGRAMMINFO
**************************************************************************************************
Funktion: LoRa Empfaenger mit WEB-Server

**************************************************************************************************
Version: 11.07.2022
**************************************************************************************************
Board: TTGO LORA32-OLED V1
**************************************************************************************************
Libraries:
https://github.com/espressif/arduino-esp32/tree/master/libraries
C:\Users\User\Documents\Arduino
D:\gittemp\Arduino II\A156_Wetterdaten_V3
**************************************************************************************************
C++ Arduino IDE V1.8.19
**************************************************************************************************
Einstellungen:
https://dl.espressif.com/dl/package_esp32_index.json
http://dan.drown.org/stm32duino/package_STM32duino_index.json
http://arduino.esp8266.com/stable/package_esp8266com_index.json
**************************************************************************************************/


// Wi-Fi Library
#include <WiFi.h>
#include "ESPAsyncWebServer.h"

#include <SPIFFS.h>

//LoRa Library
#include <SPI.h>
#include <LoRa.h>

//OLED Display Library
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

// NTP Server Library
#include <NTPClient.h>
#include <WiFiUdp.h>

//Definiere die Pins, die vom LoRa-Transceiver-Modul verwendet werden
#define SCK 5
#define MISO 19
#define MOSI 27
#define SS 18
#define RST 14
#define DIO0 26

//433E6 Asia
//866E6 Europa
//915E6 North America
#define BAND 866E6

//TTGO OLED Pins
#define OLED_SDA 21
#define OLED_SCL 22
#define OLED_RST 16
#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels


// WiFi
const char* ssid     = "xxx";
const char* password = "xxx";

// NTP-Client definieren
WiFiUDP ntpUDP;
NTPClient timeClient(ntpUDP);

// Variablen zum Speichern von Datum und Uhrzeit
String formattedDate;
String day;
String hour;
String timestamp;


// Initialisieren von Variablen zum Abrufen und Speichern von LoRa-Daten
int rssi;
String loRaMessage;
String temperature;
String humidity;
String pressure;
String readingID;

// Erstellen eines AsyncWebServer-Objekts auf Port 80
AsyncWebServer server(80);

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RST);

// Ersetze Platzhalter durch DHT-Werte
String processor(const String& var){
  //Serial.println(var);
  if(var == "TEMPERATURE"){
    return temperature;
  }
  else if(var == "HUMIDITY"){
    return humidity;
  }
  else if(var == "PRESSURE"){
    return pressure;
  }
  else if(var == "TIMESTAMP"){
    return timestamp;
  }
  else if (var == "RRSI"){
    return String(rssi);
  }
  return String();
}

//Initialisiere OLED Display
void startOLED(){
  //reset OLED display via software
  pinMode(OLED_RST, OUTPUT);
  digitalWrite(OLED_RST, LOW);
  delay(20);
  digitalWrite(OLED_RST, HIGH);

  //Initialisiere OLED
  Wire.begin(OLED_SDA, OLED_SCL);
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3c, false, false)) { // Address 0x3C for 128x32
    Serial.println(F("SSD1306 allocation failed"));
    for(;;); // Don't proceed, loop forever
  }
  display.clearDisplay();
  display.setTextColor(WHITE);
  display.setTextSize(1);
  display.setCursor(0,0);
  display.print("LORA SENDER");
}

//Initialisiere LoRa Modul
void startLoRA(){
  int counter;
  //SPI LoRa Pins
  SPI.begin(SCK, MISO, MOSI, SS);
  //LoRa-Transceiver-Modul einrichten
  LoRa.setPins(SS, RST, DIO0);

  while (!LoRa.begin(BAND) && counter < 10) {
    Serial.print(".");
    counter++;
    delay(500);
  }
  if (counter == 10) {
    // Erhöhe die Lese-ID bei jedem neuen Messwert
    Serial.println("Das Starten von LoRa ist fehlgeschlagen!");
  }
  Serial.println("LoRa-Initialisierung OK!");
  display.setCursor(0,10);
  display.clearDisplay();
  display.print("LoRa-Initialisierung OK!");
  display.display();
  delay(2000);
}

void connectWiFi(){
  // Verbinde mich mit dem Wi-Fi-Netzwerk
  Serial.print("Verbinde mit ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // Lokale IP-Adresse ausgeben und Webserver starten
  Serial.println("");
  Serial.println("WiFi verbunden.");
  Serial.println("IP Addresse: ");
  Serial.println(WiFi.localIP());
  display.setCursor(0,20);
  display.print("WEBServer IP-Addresse: ");
  display.setCursor(0,30);
  display.print(WiFi.localIP());
  display.display();
}

// Lese das LoRa-Paket und erhalte die Sensormesswerte
void getLoRaData() {
  Serial.print("Lora-Paket empfangen: ");
  // RLese Packet
  while (LoRa.available()) {
    String LoRaData = LoRa.readString();
    // LoRaData-Format: LeseID/Temperatur&Feuchtigkeit#Luftdruck
    // String Beispiel: 1/27.43&654#95.34
    Serial.print(LoRaData);

    // Lese ID, Temperatur, euchtigkeit und Luftdruck
    int pos1 = LoRaData.indexOf('/');
    int pos2 = LoRaData.indexOf('&');
    int pos3 = LoRaData.indexOf('#');
    readingID = LoRaData.substring(0, pos1);
    temperature = LoRaData.substring(pos1 +1, pos2);
    humidity = LoRaData.substring(pos2+1, pos3);
    pressure = LoRaData.substring(pos3+1, LoRaData.length());
  }
  // Lese RSSI
  rssi = LoRa.packetRssi();
  Serial.print(" mit RSSI ");
  Serial.println(rssi);
}

// Funktion zum Abrufen von Datum und Uhrzeit von NTPClient
void getTimeStamp() {
  while(!timeClient.update()) {
    timeClient.forceUpdate();
  }
  // Das formattedDate hat das folgende Format:
  // 2018-05-28T16:00:13Z
  // Wir müssen Datum und Uhrzeit extrahieren
  formattedDate = timeClient.getFormattedDate();
  Serial.println(formattedDate);

  // Datum extrahieren
  int splitT = formattedDate.indexOf("T");
  day = formattedDate.substring(0, splitT);
  Serial.println(day);
  // Zeit extrahieren
  hour = formattedDate.substring(splitT+1, formattedDate.length()-1);
  Serial.println(hour);
  timestamp = day + " " + hour;
}

void setup() {
  // Initialisiere Seriellen Monitor
  Serial.begin(115200);
  startOLED();
  startLoRA();
  connectWiFi();

  if(!SPIFFS.begin()){
    Serial.println("Beim Mounten von SPIFF ist ein Fehler aufgetreten");
    return;
  }
  // Starte WEB-Server
  server.on("/", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send(SPIFFS, "/index.html", String(), false, processor);
  });
  server.on("/temperature", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send_P(200, "text/plain", temperature.c_str());
  });
  server.on("/humidity", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send_P(200, "text/plain", humidity.c_str());
  });
  server.on("/pressure", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send_P(200, "text/plain", pressure.c_str());
  });
  server.on("/timestamp", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send_P(200, "text/plain", timestamp.c_str());
  });
  server.on("/rssi", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send_P(200, "text/plain", String(rssi).c_str());
  });
  server.on("/winter", HTTP_GET, [](AsyncWebServerRequest *request){
    request->send(SPIFFS, "/winter.jpg", "image/jpg");
  });
  // Start server
  server.begin();

  // InitialisiereNTPClient
  timeClient.begin();
  // Zeit Offset
  // GMT +1 = 3600
  // GMT +8 = 28800
  // GMT -1 = -3600
  // GMT 0 = 0
  timeClient.setTimeOffset(7200);
}

void loop() {
  // Überprüfe, ob LoRa-Pakete verfügbar sind
  int packetSize = LoRa.parsePacket();
  if (packetSize) {
    getLoRaData();
    getTimeStamp();
  }
}

RAW code

Download data Ordner

Der Serielle Monitor am Empfänger

BME280 LoRa WEB-Server