ESP32 Chat

In diesem Beispiel wird eine drahtlose Kommunikation zwischen zwei ESP32-Boards aufgebaut. Um die ESP-Verbindung zu initialisieren, müssen wir zuerst unsere ESP32-Boards koppeln. Diese Verbindung bleibt unabhängig von einem Neustart der ESPs bestehen und die Übertragung wird reibungslos fortgesetzt. Im ersten Schritt wird die MAC-Adresse des Empfängers ermittelt. Danach werden Sender und Empfänger programmiert.

Über den Seriellen Monitor wird beim Empfänger die Sende-Nachricht abgefragt.

Hardware

Die Hardware für dieses Projekt:

• 2 x ESP32

Software

Die Software für dieses Projekt:

• Wir fragen die MAC-Adresse des Empfängers ab.
• Wir laden das Empfänger-Programm.
• Wir laden das Sender-Programm.

Programm

C++ Code - MAC-Adresse abfragen:

/*************************************************************************************************
                                      PROGRAMMINFO
**************************************************************************************************
Funktion: ESP32 MAC Addresse auslesen
**************************************************************************************************
Version: 18.09.2021
**************************************************************************************************
Board: ESP32vn IoT UNO V1.0.4
**************************************************************************************************
C++ Arduino IDE V1.8.13
**************************************************************************************************
Einstellungen:
https://dl.espressif.com/dl/package_esp32_index.json
http://dan.drown.org/stm32duino/package_STM32duino_index.json
https://raw.githubusercontent.com/espressif/arduino-esp32/gh-pages/package_esp32_dev_index.json
**************************************************************************************************
Librarys
- WiFi.h V0.16.1
**************************************************************************************************
const char* ssid = "xxx";
const char* password = "xxx";


 **************************************************************************************************/

#ifdef ESP32
  #include <WiFi.h>
#else
  #include <ESP8266WiFi.h>
#endif

void setup(){
  Serial.begin(115200);
  Serial.println();
  Serial.print("ESP Board MAC Address:  ");
  Serial.println(WiFi.macAddress());
}

void loop(){

}

RAW code

C++ Code - Empfänger-Programm:

/*************************************************************************************************
                                      PROGRAMMINFO
**************************************************************************************************
Funktion: ESP32 NOW Empfaenger
**************************************************************************************************
Version: 18.09.2021
**************************************************************************************************
Board: ESP32vn IoT UNO V1.0.4
**************************************************************************************************
C++ Arduino IDE V1.8.13
**************************************************************************************************
Einstellungen:
https://dl.espressif.com/dl/package_esp32_index.json
http://dan.drown.org/stm32duino/package_STM32duino_index.json
https://raw.githubusercontent.com/espressif/arduino-esp32/gh-pages/package_esp32_dev_index.json
**************************************************************************************************
Librarys
- WiFi.h V0.16.1
**************************************************************************************************

 **************************************************************************************************/
#include <esp_now.h>
#include <WiFi.h>

typedef struct struct_message {
    char character[100];
    int integer;
    float floating_value;
    bool bool_value;
} struct_message;


struct_message message;

void data_receive(const uint8_t * mac, const uint8_t *incomingData, int len) {
  memcpy(&message, incomingData, sizeof(message));
  Serial.print("Bytes received: ");
  Serial.println(len);
  Serial.print("Char: ");
  Serial.println(message.character);
  Serial.print("Int: ");
  Serial.println(message.integer);
  Serial.print("Float: ");
  Serial.println(message.floating_value);
  Serial.print("Bool: ");
  Serial.println(message.bool_value);
  Serial.println();
}

void setup() {
  Serial.begin(115200);
  WiFi.mode(WIFI_STA);

  if (esp_now_init() != ESP_OK) {
    Serial.println("Error initializing ESP-NOW");
    return;
  }

  esp_now_register_recv_cb(data_receive);
}

void loop() {

}

RAW code

C++ Code - Sender-Programm:

/*************************************************************************************************
                                      PROGRAMMINFO
**************************************************************************************************
Funktion: ESP32 NOW Sender Hallo Fraenky
**************************************************************************************************
Version: 18.09.2021
**************************************************************************************************
Board: ESP32vn IoT UNO V1.0.4
Board: ESP36 Dev Module
**************************************************************************************************
C++ Arduino IDE V1.8.13
**************************************************************************************************
Einstellungen:
https://dl.espressif.com/dl/package_esp32_index.json
http://dan.drown.org/stm32duino/package_STM32duino_index.json
https://raw.githubusercontent.com/espressif/arduino-esp32/gh-pages/package_esp32_dev_index.json
**************************************************************************************************
Librarys
- WiFi.h V0.16.1
**************************************************************************************************
const char* ssid = "xxx";
const char* password = "xxx";

 **************************************************************************************************/
#include <esp_now.h>
#include <WiFi.h>

// REPLACE WITH YOUR RECEIVER MAC Address
uint8_t broadcastAddress[] = {0x7C, 0x9E, 0xBD, 0x37, 0xCA, 0x84};

typedef struct struct_message {
  char character[100];
  int integer;
  float floating_value;
  bool bool_value;
} struct_message;

struct_message message;

void data_sent(const uint8_t *mac_addr, esp_now_send_status_t status) {
  Serial.print("\r\nStatus of Last Message Sent:\t");
  Serial.println(status == ESP_NOW_SEND_SUCCESS ? "Delivery Success" : "Delivery Fail");
}

void setup() {

  Serial.begin(115200);
  WiFi.mode(WIFI_STA);

  if (esp_now_init() != ESP_OK) {
    Serial.println("Error initializing ESP-NOW");
    return;
  }

  esp_now_register_send_cb(data_sent);

  esp_now_peer_info_t peerInfo;
  memcpy(peerInfo.peer_addr, broadcastAddress, 6);
  peerInfo.channel = 0;
  peerInfo.encrypt = false;
  if (esp_now_add_peer(&peerInfo) != ESP_OK){
    Serial.println("Failed to add peer");
    return;
  }
}

void loop() {

  strcpy(message.character, "Hallo Fränky!");
  message.integer = random(1,10);
  message.floating_value = 5.6;
  message.bool_value = true;

  esp_err_t outcome = esp_now_send(broadcastAddress, (uint8_t *) &message, sizeof(message));

  if (outcome == ESP_OK) {
    Serial.println("Mesage sent successfully!");
  }
  else {
    Serial.println("Error sending the message");
  }
  delay(2000);
}

RAW code

nach oben